Учимся Патчить Прошивку! C помощью проги Binedit, Нужен Мануальчик от наших ГУРУ Поделиться Опции

[fkcoder]

Fenja, Да. Ищи в либе BEGIN_4A__IN_DB. К этому значению прибавиш оффсет нужного значения в симе 4а. И таким же макаром из 807 вычитаеш BEGIN_4A__IN_DB для той прошивки с которой портируешь и получаешь нужный оффсет в симе
должно через = писаться)

[Umka85]

А почему через _ пишется?

А чтобы его на адрес не посчитали. Можно писать что хочешь. Это же название, а не офсет

[CVARC]

Я понимаю что вопрос тупой но,скажите где в бине калькулятор кода а то никак не разберусь,на вкладке инструменты есть калькулятор жму вылазит виндозный а мне нужен тот что код в HEX переводит,бин тот что на сайте в программах.

[Fenja]

где в бине калькулятор кода а то никак не разберусь

Инструменты => Компилятор => Вид => Режим калькулятора.

[fkcoder]

CVARC, в HEX то переводит как раз стандартный виндозный калькулятор

[Fenja]

Может кто нить подсказать функцию, которая запускается при старте будильника и выставляет иконку активного будильника в статус строку?
Кусок типа:

Код

MOV     R0, #0x7A
BL      _Ven_TA_S__UIS_SetStatus

В AlarmStart я что т ничего не нашел
Может AlmclkReminderInitHandleBegin?

[CVARC]

А у мя назрел такой злосный вопрос
Как посчитать ссылку на адрес если в патченой проше строка имеет вид

Код

103E76F0:    F4E7FD02    BL    off_100CF0F8

а при перещёте калькулятор кода выдаёт такое

Код

BL    off_100CF0F8                F7FFFFFE

причём калькулятор считает все данные нормально,проверено экспериментальным путём,а именно ссылки переходов выдаёт одно и тоже F7FFFFFE.

[Джуманджи]

Fenja,
в проше ты этого не найдешь, только в патче. Вроде это:

continue_set_alarm_icon:
MOV R0, #0x9D
ADD R2, SP, #0x4
.hex CA06
BL _Ven_TA_S__UIS_SetStatus_0

ADD SP, #0x10
POP {R0-R7,PC}
.patchcoment "set_alarm_icon"

CVARC,
адрес откуда идет переход, тоже надо вводить. и все заработает

[Fenja]

в проше ты этого не найдешь

А как же тогда ричуется иконка, когда срабатывает будильник?

только в патче

Патч то у меня есть..

Код

alarm_not_exist:

        ADD     R3, SP, #0x0       
        STRB    R0, [R3]            
        ADD     R2, SP, #0x0
        LDMIA   R2!, {R1,R2}       
        MOV     R0, #0x7A          
        BL      _Ven_TA_S__UIS_SetStatus
        ADD     SP, #0x10
        POP     {R0-R7,PC}

[fkcoder]

CVARC,
юзай компилятор

Код

.start 0x103E76F0
BL    0x100CF0F8

Fenja,

Может AlmclkReminderInitHandleBegin?

скорее всего. а для чего тебе это?

[Fenja]

а для чего тебе это?

У меня при срабатывании будильника в статус строке 2 иконки.
1 - иконка от патча "Иконка будильнька в сс"
2 - иконка звенящего будильника
Я хочу передвинуть иконку активного будильника левее, это уже получилось и занопить функцию, которая рисует иконку будильника при звенящем будильнике
Только функцию AlmclkReminderInitHandleBegin на своей проше пока найти не могу...

[fkcoder]

Fenja, патч Часы в СС и файл REGION_TABLE не позволяет этого сделать?)

[Fenja]

патч Часы в СС и файл REGION_TABLE не позволяет этого сделать?)

Не знаю у меня патч на часы в сс без чтения REGION_TABLE
А с REGION_TABLE еще надо портировать, точнее протестить

[CVARC]

CVARC,
юзай компилятор

Код

.start 0x103E76F0
BL    0x100CF0F8

'lavmen'
Спасибо,компилятор рулит !

[Джуманджи]

Fenja,
посмотри это

Spoiler:

set_alarm_icon_blink:
PUSH {R0-R7,LR}
SUB SP, #0x10

MOV R0, #0x2 ;UIS_ALARM_CLK_STATUS_BLINK
STR R0, [SP,#0x4]

MOV R0, #0x9D
ADD R2, SP, #0x4
.hex CA06
BL _Ven_TA_S__UIS_SetStatus_0

ADD SP, #0x10
POP {R0-R7}

MOV R2, #0x0
MOV R1, #0x0

POP {PC}
.patchcoment "set_alarm_icon_blink"

[close]

[Fenja]

Джуманджи,
Что ты хочешь этим сказать? Это часть исходника патча на иконку будильника в сс.
Только у меня код отличается немного...
lavmen,
а как зачем мне REGION_TABLE? Я и так патчем иконки сдвину если надо...

Сообщение отредактировал Fenja - 29.7.2009, 12:08

[fkcoder]

Fenja, помоему удобнее в одном файлике сменить пару байт чем мучатся с патчами)

[Джуманджи]

Что ты хочешь этим сказать? Это часть исходника патча на иконку будильника в сс.
Только у меня код отличается немного...

это кусок кода, который выводит мигающую иконку в сс.

[Fenja]

lavmen,
у меня есть исходник патча на часы в сс, но там REGION_TABLE размером 160 байт, описания я видел тока к 96 байтному.
И разве содержимое файла REGION_TABLE не заменяется патчем Свобода в сс?

это кусок кода, который выводит мигающую иконку в сс.

надо будет испробывать

Сообщение отредактировал Fenja - 29.7.2009, 17:36

[Fenja]

Джуманджи,
а можешь выложить полностью исходник?

[Osta]

_Ven_TA_S__UIS_SetStatus

очень интересная функция , разбирался с ней когда делал патч Домик у оператора
тогда же для тестов сделал патч , при входе в справочник срабатывает посылка
числа из 13-го байта сима 004а в функцию UIS_SetStatus
Число в этот байт устанавливал с помощью VC
Очень интересные результаты были ))

Spoiler:

.equ _Ven_TA_S__UIS_SetStatus_0 0x105608A4
.equ _Ven_TT_L__DL_DbFeatureGetCurrentState 0x10560700

.start 0x10853DB6 // APP_PHBK_MainListViewEnter
BL ricon


.start 0x10832558 // пустота или log-строчки

ricon:
MOV R0, #0
MOV R5, #0

PUSH {R0-R7,LR}
SUB SP, #0x20
MOV R0, #0x1
ADD R3, SP, #0x0
STRB R0, [R3]
ADD R2, SP, #0x0
.hex CA06
LDR R0, =0x00000625 // 13 байт seem 004a
BL get_current_state
BL _Ven_TA_S__UIS_SetStatus_0
ADD SP, #0x20
POP {R0-R7,PC}
.data
.patchcoment "ricon"

.start 0x10832588 // пустота или log-строчки
get_current_state:
PUSH {R1-R7,LR}
SUB SP, #0x4
MOV R1, SP
BL _Ven_TT_L__DL_DbFeatureGetCurrentState
ADD R3, SP, #0x0
LDRB R0, [R3]
ADD SP, #0x4
POP {R1-R7,PC}
.data
.patchcoment "get_current_state"

[close]

[Fenja]

Osta,
Надо попробывать
А зачем нужна?

Код

.start 0x10853DB6 // APP_PHBK_MainListViewEnter
BL remove_rc_icon

remove_rc_icon что т я не вижу где эта функция...

Очень интересные результаты были ))

Я седня что т в исходнике на иконку будильника в сс намудрил, у меня при выключеном будильнике в сс мигала иконка будильника

Сообщение отредактировал Fenja - 31.7.2009, 13:31

[Osta]

remove_rc_icon что т я не вижу где эта функция...

исправил

[Джуманджи]

а можешь выложить полностью исходник?

это патч для К1

Spoiler:

.start 0x1041D30A
BL set_alarm_icon_blink
.patchcoment "AlmclkReminderUtilPlayStopTone"

.start 0x105BAE70 ;"PERSKeysSelectSendListData : Exit %d.."
.string "%d"

set_alarm_icon_blink:
PUSH {R0-R7,LR}
SUB SP, #0x10

MOV R0, #0x2 ;UIS_ALARM_CLK_STATUS_BLINK
STR R0, [SP,#0x4]

MOV R0, #0x9D
ADD R2, SP, #0x4
.hex CA06
BL _Ven_TA_S__UIS_SetStatus_0

ADD SP, #0x10
POP {R0-R7}

MOV R2, #0x0
MOV R1, #0x0

POP {PC}
.patchcoment "set_alarm_icon_blink"

.start 0x1041D392
BL AlmclkReminderUtilPlayStopTone_return_style
.patchcoment "AlmclkReminderUtilPlayStopTone 1"

.start 0x105BAF08 ;"PERSKeysWaitingHandleData: Exit %d.."
.string "%d"

AlmclkReminderUtilPlayStopTone_return_style:
STRB R0, [R4, #0x5]
STR R0, [R5, #0x6C]
PUSH {LR}
BL set_alarm_icon
POP {PC}
.patchcoment "AlmclkReminderUtilPlayStopTone_return_style"

.start 0x10F10E4E
BL set_alarm_icon_
POP {R3-R7}
POP {R3}
BX R3
.patchcoment "dbSrvAlmclkModifyRecord__15DL_DB_ALMCLK_SPSFP21DL_DB_ALMCLK_RECORD_T"

.start 0x10DF05D8 ;"MStreamTell- MEMORY_FLAG hStream->file_handle NULL - FAILED "
.string "FF"
set_alarm_icon_:
BX PC
.code 32
LDR R12, =_set_alarm_icon_+1
BX R12
.code 16

.start 0x105BB148 ;"PERSKeysWaitingHandleHomeKey : Exit %d, p_homekey_items.."
.string "%d"

_set_alarm_icon_:
MOV R0, R4

set_alarm_icon:
PUSH {R0-R7,LR}
SUB SP, #0x10
MOV R0, #0x0 ;UIS_ALARM_CLK_STATUS_OFF
STR R0, [SP,#0x4]

MOV R1, SP
MOV R0, #0x1 ;DL_DB_ALMCLK_QUERY_ENABLED_NUMBER
BL my_dbSrvAlmclkGetNumberOfRecords__15DL_DB_ALMCLK_SPSFUcPUc

CMP R0, #0x0
BNE alarm_not_exist

ADD R3, SP, #0x0
LDRB R0, [R3, #0x0]
CMP R0, #0x0
BEQ alarm_not_exist

MOV R0, #0x1 ;UIS_ALARM_CLK_STATUS_ON
STR R0, [SP,#0x4]

alarm_not_exist:
B continue_set_alarm_icon

.start 0x105BB190 ;"PERSKeysWaitingHandleHomeKey : Exit %d.."
.string "%d"

continue_set_alarm_icon:
MOV R0, #0x9D
ADD R2, SP, #0x4
.hex CA06
BL _Ven_TA_S__UIS_SetStatus_0

ADD SP, #0x10
POP {R0-R7,PC}
.patchcoment "set_alarm_icon"

.start 0x105BB258 ;"PERSKeysMenuHandleNavigate : Exit %d.."
.string "%d"

my_dbSrvAlmclkGetNumberOfRecords__15DL_DB_ALMCLK_SPSFUcPUc:
BX PC
.code 32
LDR R12, =dbSrvAlmclkGetNumberOfRecords__15DL_DB_ALMCLK_SPSFUcPUc+1
BX R12
.code 16

.start 0x10732EAC
BL set_alarm_icon
.patchcoment "IdleHandleALSPowerupOrAlsChange"

.start 0x105BB3F0 ;"PERSKeysMenuHandleNavigate : Exit %d, Switch Default.."
.string "%d"

my_AlmclkFormExitApp:
MOV R1, R4
MOV R0, R7

continue_my_Almclk:
PUSH {LR}
BL set_alarm_icon
POP {PC}
.patchcoment "my_AlmclkFormExitApp"

my_AlmclkMainDeleteHandleYes:
MOV R2, R5
MOV R1, R6
B continue_my_Almclk
.patchcoment "my_AlmclkMainDeleteHandleYes"

my_AlmclkMainListViewHandleDeleteSingle:
MOV R2, R6
MOV R1, R4
B continue_my_Almclk
.patchcoment "my_AlmclkMainListViewHandleDeleteSingle"

.start 0x1041C67E
BL my_AlmclkFormExitApp
.patchcoment "AlmclkFormExitApp"

.start 0x1041BBF8
BL my_AlmclkMainDeleteHandleYes
.patchcoment "AlmclkMainDeleteHandleYes"

.start 0x1041B906
BL my_AlmclkMainListViewHandleDeleteSingle
.patchcoment "AlmclkMainListViewHandleDeleteSingle"

[close]

[Fenja]

Джуманджи,
Это вырезка из патча Кукушка?

[Джуманджи]

Джуманджи,
Это вырезка из патча Кукушка?

нет, отдельный патч.

Добавлено позже (2.8.2009, 23:32):
Fenja,
вот более новая версия патча

Spoiler:

.start 0x1041D30A
BL set_alarm_icon_blink
.patchcoment "AlmclkReminderUtilPlayStopTone"

.start 0x105BAE70 ;"PERSKeysSelectSendListData : Exit %d.."
.string "%d"

set_alarm_icon_blink:
PUSH {R0-R7,LR}
SUB SP, #0x10

MOV R0, #0x1 ;UIS_STATUS_BLINK
ADD R2, SP, #0x0
STRB R0, [R2, #0x0]

; LDMIA R2!, {R1,R2} ;Загрузить регистры R1,R2 по адресу из R2
.hex CA06

MOV R0, #0x8E
BL _Ven_TA_S__UIS_SetStatus_0

ADD SP, #0x10
POP {R0-R7}

MOV R2, #0x0
MOV R1, #0x0

POP {PC}
.patchcoment "set_alarm_icon_blink"

.start 0x1041D392
BL AlmclkReminderUtilPlayStopTone_return_style
.patchcoment "AlmclkReminderUtilPlayStopTone 1"

.start 0x105BAF08 ;"PERSKeysWaitingHandleData: Exit %d.."
.string "%d"

AlmclkReminderUtilPlayStopTone_return_style:
STRB R0, [R4, #0x5]
STR R0, [R5, #0x6C]
PUSH {LR}
BL set_alarm_icon
POP {PC}
.patchcoment "AlmclkReminderUtilPlayStopTone_return_style"

.start 0x10F10E4E
BL set_alarm_icon_
POP {R3-R7}
POP {R3}
BX R3
.patchcoment "dbSrvAlmclkModifyRecord__15DL_DB_ALMCLK_SPSFP21DL_DB_ALMCLK_RECORD_T"

.start 0x10DF05D8 ;"MStreamTell- MEMORY_FLAG hStream->file_handle NULL - FAILED "
.string "FF"
set_alarm_icon_:
BX PC
.code 32
LDR R12, =_set_alarm_icon_+1
BX R12
.code 16

.start 0x105BB148 ;"PERSKeysWaitingHandleHomeKey : Exit %d, p_homekey_items.."
.string "%d"

_set_alarm_icon_:
MOV R0, R4

set_alarm_icon:
PUSH {R0-R7,LR}
SUB SP, #0x10

MOV R1, SP
MOV R0, #0x1 ;DL_DB_ALMCLK_QUERY_ENABLED_NUMBER
BL my_dbSrvAlmclkGetNumberOfRecords__15DL_DB_ALMCLK_SPSFUcPUc

CMP R0, #0x0
MOV R0, #0x0 ;UIS_ALARM_CLK_STATUS_OFF
BNE alarm_not_exist

ADD R3, SP, #0x0
LDRB R0, [R3, #0x0]
CMP R0, #0x0
BEQ alarm_not_exist

MOV R0, #0x1 ;UIS_ALARM_CLK_STATUS_ON

alarm_not_exist:
B continue_set_alarm_icon

.start 0x105BB190 ;"PERSKeysWaitingHandleHomeKey : Exit %d.."
.string "%d"

continue_set_alarm_icon:
ADD R2, SP, #0x0
STRB R0, [R2, #0x0]

; LDMIA R2!, {R1,R2} ;Загрузить регистры R1,R2 по адресу из R2
.hex CA06

MOV R0, #0x7B
BL _Ven_TA_S__UIS_SetStatus_0

B continue_set_alarm_icon_

.start 0x105BB1E0 ;"PERSKeysMenuHandleDone : Exit %d.."
.string "%d"

continue_set_alarm_icon_:
MOV R0, #0x0
ADD R2, SP, #0x0
STRB R0, [R2, #0x0]

; LDMIA R2!, {R1,R2} ;Загрузить регистры R1,R2 по адресу из R2
.hex CA06

MOV R0, #0x8E
BL _Ven_TA_S__UIS_SetStatus_0

ADD SP, #0x10
POP {R0-R7,PC}
.patchcoment "set_alarm_icon"

.start 0x105BB258 ;"PERSKeysMenuHandleNavigate : Exit %d.."
.string "%d"

my_dbSrvAlmclkGetNumberOfRecords__15DL_DB_ALMCLK_SPSFUcPUc:
BX PC
.code 32
LDR R12, =dbSrvAlmclkGetNumberOfRecords__15DL_DB_ALMCLK_SPSFUcPUc+1
BX R12
.code 16

.start 0x10732EAC
BL set_alarm_icon
.patchcoment "IdleHandleALSPowerupOrAlsChange"

.start 0x105BB3F0 ;"PERSKeysMenuHandleNavigate : Exit %d, Switch Default.."
.string "%d"

my_AlmclkFormExitApp:
MOV R1, R4
MOV R0, R7

continue_my_Almclk:
PUSH {LR}
BL set_alarm_icon
POP {PC}
.patchcoment "my_AlmclkFormExitApp"

my_AlmclkMainDeleteHandleYes:
MOV R2, R5
MOV R1, R6
B continue_my_Almclk
.patchcoment "my_AlmclkMainDeleteHandleYes"

my_AlmclkMainListViewHandleDeleteSingle:
MOV R2, R6
MOV R1, R4
B continue_my_Almclk
.patchcoment "my_AlmclkMainListViewHandleDeleteSingle"

.start 0x1041C67E
BL my_AlmclkFormExitApp
.patchcoment "AlmclkFormExitApp"

.start 0x1041BBF8
BL my_AlmclkMainDeleteHandleYes
.patchcoment "AlmclkMainDeleteHandleYes"

.start 0x1041B906
BL my_AlmclkMainListViewHandleDeleteSingle
.patchcoment "AlmclkMainListViewHandleDeleteSingle"

[close]

[CVARC]

портирую патч sis hear java 1400 korelet 57 elf 7x 118 с v360 ACR на v360 AER все переходы нашол,всё один в один как в проше источнике.
эльфы работают,ява работает опера мод показывает 1,3 метра памяти,мини командер 1,4 метра, все приложения запускаются только один раз после выхода ява не запускается,фото и видео камера пишет : занято повторите позже,после перезагруза таже ситуация.
портил с помощью бина,исходника у меня нет поэтому просто сделал копию патча просто изменив переходы и смещения.
гдето здесь читал непомню где что создать исходник для патча памати неполучится поэтому делал в ручную
Вобщем по симптомам я так думаю что ява не возвращает системе что память свободна
если ошибся подскажите плиз где.


Сообщение отредактировал CVARC - 23.8.2009, 22:46

[CVARC]

Всем спасибо : ) ,месяц мучений и 1400 kb памяти на яву ,БЕЗ ИСХОДНИКА,отвоёвано,осталось отвоевать памяти эльфам.P.S. Сори за оффтоп.

[CVARC]

Прошу подскажите
неполучаетя откомпилить следующее

Код

.start 0x102F6D90BL           _off_0x10C8E30C;(компенсирован) Переход по адресу 0x10C8E30C с сохранением адреса возврата

записываю так

Код

.start 0x102F6D90
BL 0x10C8E30C

а получается

Код

+10092000
00264D90: F000F800B40348019001BD0110C8E30D      -16 БАЙТ

-16 БАЙТ
а надо XXXXXXXX -8 БАЙТ

[Евгений89]

CVARC, я так понимаю ты открываешь пропатченную прошивку в бинэдите и получаешь такое

Код

102F6D90 BL           _off_0x10C8E30C;

убери галочку в настройках бинэдита "подменять дальние переходы через BLX"

просто с адреса 102F6D90 надо перейти на адрес 10C8E30C, но для команды BL это далеко, поэтому происходит переход на какой-то промежуточный адрес а от туда уже на 10C8E30C, а в бинэдите пишется

Код

102F6D90 BL           _off_0x10C8E30C;

как будто сразу переходит на 10C8E30C. После того как уберешь галочку с адреса 102F6D90 будет переход на какой-то промежуточный адрес.

PS как-то каряво объяснил, но думаю понятно


Сообщение отредактировал Евгений89 - 4.11.2009, 18:51

[CVARC]

PS как-то каряво объяснил, но думаю понятно

Правильно думаеш,спасибо

[CVARC]

Привет,у меня снова вопрос:компилятор бина выдаёт ошибку:отсутствует параметр в вычислениях при компил.следующей строки:SUB SP,(4+(6+2+255+1)*2) ,подкажите плиз что здесь нужно редактировать,патч часы в СС

[Fenja]

подкажите плиз что здесь нужно редактировать,

Ничего, все норм

[Fenja]

Так, по порядку
На V3i есть патч Часы_в_статус-строке1.76, в котором местоположение иконок внешнего и внутреннего дисплеев берутся из REGION_TABLE размером 160 байт, цвет часов и контур берутся из скина

контур - это CLI_OUTLINE_TEXT

Я так понял, что статус строка в этом патче рисуется следующим куском кода

Spoiler:

Код

draw_clock_in_status_line_formatter_exists:
        MOV     R1, #0x3A; ':'
        LDR     R0, =colmgr
        BL      getColor__12ColorManagerFUc
        STR     R0, [SP,#0x24]
        STR     R0, [SP,#0x38]
        MOV     R1, #2
        LDR     R0, =colmgr
        BL      getColor__12ColorManagerFUc
        STR     R0, [SP,#0x24]
        STR     R0, [SP,#0x34]
        MOV     R0, #0
        STRB    R0, [SP,#0x31]
        MOV     R0, #0
        STRB    R0, [SP,#0x32]
        MOV     R0, #0x11
        STRB    R0, [SP,#0x30]
        MOV     R0, #0
        STRB    R0, [SP,#0x33]
        MOV     R1, #0x47; 'G'
        LDR     R0, =colmgr
        BL      getColor__12ColorManagerFUc
        MOV     R1, #0x47; 'G'
        STR     R0, [SP,#0x24]
        LDR     R0, =colmgr
        BL      getColor__12ColorManagerFUc
        MOV     R2, #0
        STR     R0, [SP,#0x20]
        LDR     R1, [SP,#0x24]
        BL      setTextOutline__18HSC_Base_RectangleSF11UIS_COLOR_TT1Sc
        MOV     R3, #0x0
        MOV     R2, #0x1
        LDR     R0, =activeDisplayID__6Dialog
        LDRB    R1, [R0,#0x0]
        MOV     R0, #0x1
        ADD     R12, SP, #0x10
        STMIA   R12, {R0-R3}
        LDR     R0, =weekviewFont__16DisplayFormatter
        LDRB    R1, [R0,#0x0]
        ADD     R0, SP, #0x30
        STMEA   SP, {R0-R3}
        ADD     R3, SP, #0x28
        ADD     R2, SP, #0x44
        LDR     R0, =formatter
        LDR     R1, [R0,#0x0]
        ADD     R0, SP, #0x20
        BL      drawOneLine__16DisplayFormatterFP10UI_CONTENTRC24tag_DAL_GRAPHIC_REGION_TR28UIS_GRAPHIC_RECTANGLE_ATTRIBUcT4P23tag_DAL_GRAPHIC_POINT_TScT4T7PUs
        BL      unsetTextOutline__18HSC_Base_RectangleSFv; unsetTextOutline(void)

[close]

Требуется найти место, где идет загрузка контура часов из скина и прописать там 0x0, что бы заливки не было
Есть так же патч на часы в сс, с REGION_TABLE размером 96 байт. Я его портировал, цвет/заливка часов задается в REGION_TABLE, то есть все норм, если бы не одно но: на внешнем дисплее не отображается статус строка.

Сообщение отредактировал Fenja - 1.12.2009, 20:54

[Fenja]

Требуется найти место, где идет загрузка контура часов из скина и прописать там 0x0, что бы заливки не было

Хм...

Код

        STRB    R0, [SP,#0x30]
        MOV     R0, #0
        STRB    R0, [SP,#0x33]
;        MOV     R1, #0x47; 'G'
;        LDR     R0, =colmgr
;        BL      getColor__12ColorManagerFUc
;        MOV     R1, #0x47; 'G'
        LDR     R0, =0xFF
        STR     R0, [SP,#0x24]

Прописал так, вокруг часов появился белый контур, пробывал LDR R0, =0x00, аналогично

[fkcoder]

Fenja, ID контура передается в R1. проверяй все вызовы на ColorManager.
и да. ты не забыл что цвет это 4х байтное значение? то что ты передаеш - 000000FF- черный прозрачнъй цвет. Попробуй 33333333(например)

[Fenja]

ты не забыл что цвет это 4х байтное значение?

забыл

Попробуй 33333333

Как лучше писать:

Код

LDR     R0, =0x33333333

Или

Код

LDR     R0, date

.align 4
date:
     DCD 0x33333333
     .align 1

[fkcoder]

Fenja, это тоже самое) Во втором случае ты сам выбираешь где размещать значение, в первом - компилятор воткнет его в конец патча

[Fenja]

Попробуй 33333333(например)

Написал

Код

LDR     R0, =0xFF0033FF

Получилось

Значит надо попробывать в другом месте

Fenja, ID контура передается в R1. проверяй все вызовы на ColorManager.

Вот в тех строках, что я закоментил:

Код

BL      getColor__12ColorManagerFUc
        MOV     R1, #0x47; 'G'

Если я правильно понял, то после вызова функции в R1 будет результат работы функции, а потом в него копируется 0x47, причем предыдущее значение теряется

Сообщение отредактировал Fenja - 12.12.2009, 13:02

[fkcoder]

Fenja,
1) А что нибудь поменялось? Ну то есть этот цвет где нибудь появился?2) все функции возвращают результат в R0.